Skipping the Classic Shell Welcome Screen

Here’s a short guide that was a bit too much to fit into the reference materials section.

Logo-ClassicShell-AlphaI had been asked to install Classic Shell on some laptops and tablets for deployment. As part of the deployment process, I went ahead a built in into the reference image that would be used. In order to prevent the Classic Shell welcome screen from appearing at first logon I added the configuration registry keys to the default registry hive.

The below script will mount the default registry hive, insert the keys, and unmount the hive for you.

CODE (ClassicShellDefaults.bat)

@ECHO off
TITLE Set Classic Shell Defaults

ECHO ********************************************
ECHO Set Classic Shell Defaults for Default User
ECHO ********************************************
ECHO Setting Classic Shell defaults to skip options screen at new
ECHO user logon.

rem Set Defaults for Classic Shell to skip options screen

reg load "hku\temp" "%USERPROFILE%\..\Default User\NTUSER.DAT"

rem Windows 7 style
reg ADD "hku\temp\Software\IvoSoft\ClassicStartMenu\Settings"
reg ADD "hku\temp\Software\IvoSoft\ClassicShell\Settings"
reg ADD "hku\temp\Software\IvoSoft\ClassicStartMenu" /v ShowedStyle2 /t REG_DWORD /d 0x1 /f
reg ADD "hku\temp\Software\IvoSoft\ClassicStartMenu\Settings" /v SkipMetro /t REG_DWORD /d 0x1 /f
reg ADD "hku\temp\Software\IvoSoft\ClassicStartMenu\Settings" /v Version /t REG_DWORD /d 0x04020004 /f

rem Bypass start screen at logon
reg ADD "hku\temp\Software\Microsoft\Windows\CurrentVersion\Explorer\StartPage" /v OpenAtLogon /t REG_DWORD /d 0x0 /f

reg unload "hku\temp"

ECHO Complete!

ping -n 5 localhost >nul

Bonus .MST file (MSI transform file) to install only the Classic Start feature (useful for Group Policy, command line, and other automated installs).

Unpack the MSI files from the Classic Shell executable from the command line with parameter extract32 or extract64 based on your needs, then deploy with this file.

This transform was created with Orca for v4.2.1 x64.

Available Here